圣源电子制作

 找回密码
 立即注册
查看: 16887|回复: 3

自做红外遥控解码-HT6221遥控-遥控电脑-汇编程序-制作DIY

[复制链接]
发表于 2011-10-10 14:18:22 | 显示全部楼层 |阅读模式
转载自互联网!!!
         你家里是否有一个电视机遥控器或者空调机遥控器呢?你是否也想让它遥控其他的电器甚至让它遥控您的电脑呢?那好,跟我一起做这个“红外遥控解码器”。
     该小制作所需要的元件很少:单片机TA89C2051一只,RS232接口电平与TTL电平转换心片MAX232CPE一只,红外接收管一只,晶振11.0592MHz,电解电容10uF4只,10uF一只,电阻1K1个,300欧姆左右1个,瓷片电容30P2个。发光二极管8个。价钱不足20元。
电路原理介绍:
syyyd.com-00000 (2).bmp
        主控制单元是单片机AT89C2051,中断口INT0跟红外接受管U1相连,接收红外信号的脉冲,8个发光二极管作为显示解码输出(也可以用来扩展接其他控制电路),U3是跟电脑串行口RS232相连时的电平转换心片,9、10脚分别与单片机的1、2脚相连,(1脚为串行接收,2脚为串行发送),MAX232CPE的7、8脚分别接电脑串行口的2(接收)脚、3(发送脚)。晶振采用11.0592MHz,这样才能使得通讯的波特率达到9600b/s,电脑一般默认值是9600b/s、8位数据位、1位停止位、无校验位。电路就这么简单了,现在分析具体的编程过程吧。
如图所示,panasonic遥控器的波形是这样的(经过反复测试的结果)。
syyyd.com-00000 (1).bmp
         开始位是以3.6ms低电平然后是3.6ms高电平,然后数据表示形式是0.9ms低电平0.9ms高电平周期为1.8ms表示“0”, 0.9ms低电平 2.4ms高电平周期为3.3ms表示“1”,编写程序时,以大于3.4ms小于3.8ms高电平为起始位,以大于2.2ms小于2.7ms高电平表示“1”,大于0.84ms小于1.11ms高电平表示“0”。因此,我们主要用单片机测量高电平的长短来确定是“1”还是“0”即可。定时器0的工作方式设置为方式1:mov tmod,#09h,这样设置定时器0即是把GATE置1,16位计数器,最大计数值为2的16次方个机器周期,此方式由外中断INT0控制,即INT0为高时才允许计数器计数。比如:
jnb p3.2,$
jb p3.2,$
clr tr0
这3条指令就可以测量一个高电平,接下来读取计数值TH0,TL0就可以分辨是起始位还是“1”或“0”。在确定码表之前,您可以使用P0口的8个发光二极管来显示编码,16位编码分两次显示:
mov p0,keydata
acall delay_1s ;//1ms延时子程序
mov p0,keydata+1
ljmp main
根据P0相继的两次显示的编码,记录每个按键的编码,形成编码表,即遥控器编码的解码完毕。码表确定之后,以后接收到遥控器的编码之后,就与码表比较,找到匹配的码项,并把该码项对应的顺序号输出到P0口,同时也把顺序号向串行口输出到电脑,电脑接收该数据后由串口软件决定如何处理。
          程序不长,下面是完整的程序和注释:(先看流程图)
syyyd.com-00000 (3).jpg
  1. keydata equ 30h ;//该地址和31H地址用来存放遥控器按键编码。

  2. org 00h

  3. main:

  4.     mov keydata,#0    ;// 清零

  5.     mov tmod ,#09h       ;//设置定时0方式1,GATE=1

  6.        mov  r7,#0    ;//计数器,用来计数是否满8位

  7.     mov  r6,#0    ;//计数器,用来计数是否满2字节(解16位编码)

  8.     jb p3.2,[        DISCUZ_CODE_7        ]nbsp;    ;//是否为低电平

  9. again:            ;//如果为低,继续往下面执行

  10.     mov tl0,#0    ;//清零TL0

  11.     mov th0,#0     ;//清零TH0

  12.     setb tr0      ;//开启定时器0

  13.     jnb p3.2,[        DISCUZ_CODE_7        ]nbsp;   ;//等待高电平到来

  14.     jb p3.2,[        DISCUZ_CODE_7        ]nbsp; ;//高电平到来,此时开始计数

  15.     clr tr0    ;//高电平结束,停止计数

  16.     mov a,th0  ;//读取th0 值,TL0忽略不计

  17.     clr c      ;//

  18.     subb a,#12 ;//

  19.     jc again   ;//th0<12则转,即小于3.4ms,你可以算一下这个时间

  20.     mov a,#14  ;//

  21.     clr c      ;//

  22.     subb a,th0 ;//和14比较,如果TH0>14则大于3.8ms

  23.         jc again     ;//大于3.8ms,从新再检测

  24. nextbit:      ;//起始位找到了,然后下一位

  25.     mov tl0,#0 ;//

  26.     mov th0,#0 ;//

  27.     setb tr0   ;//启动定时器

  28.     jnb p3.2,$ ;//等待高电平

  29.     jb p3.2,$ ;//高电平到来,此时开始计数

  30.     clr tr0    ;//高电平结束,停止计数

  31.     mov a,th0  ;//读取计数值,TL0忽略不计

  32.     clr c      ;//

  33.     subb a,#8  ;//th0和8比较

  34.     jc next  ;;;;//若 <2.2ms则转,再判断是否大于0.84ms

  35.     mov a,#10  ;//再跟10比较

  36.     clr c      ;//

  37.     subb a,th0 ;//

  38.     jc again ;;;;;;;//若 >2.7ms,则放弃,从新检测

  39.     mov a,keydata ;// 符合大于2.2ms 小于2.7ms,即为“1”

  40.     setb c        ;//C = 1

  41.     rrc a      ;//把1移位进A

  42.     mov keydata,a ;//保存

  43.     inc r7     ;//计数器加1

  44.     cjne r7,#8,nextbit   ;//是否满8位

  45.     inc r6        ;//计数加1

  46.     cjne r6,#2,last8  ;//是否满两字节

  47.     sjmp seach    ;//不满两字节,再新采集

  48. last8:            ;//满1字节,再接下来第二字节

  49.     mov keydata+1,a   ;//把第一字节编码数据保存到31h里

  50.     mov r7,#0     ;//计数器R7清零

  51.     sjmp nextbit      ;//继续采集数据

  52. next:             ;//小于2.2ms时转到这里

  53.     mov a,th0     ;//读取计数值TH0

  54.     swap a        ;//高4位与低4位对换

  55.     mov r1,a      ;//保存到R1

  56.     anl tl0,#0f0h     ;//取TL0高4位,低4位忽略不计

  57.     mov a,tl0     ;//

  58.     clr c         ;//

  59.     rrc a      ;//

  60.     rrc a      ;//

  61.     rrc a      ;//

  62.     rrc a      ;//

  63.     add a,r1   ;//

  64.     mov r1,a   ;//

  65.     subb a,#30 ;//以上几行是把TH0的低4位和TL0的高4位合并为1字节作为计数值

  66.     jc nextbit ; //判断是否 <0.84ms,是则放弃,继续采集

  67.     mov a,r1   ;//否

  68.     clr c      ;//

  69.     cjne a,#64,continue   ;//跟64比较

  70. continue:     ;//

  71.     jnc nextbit ;  //a>64表示采样值 >1.11ms  放弃

  72.     mov a,keydata  ;//否则 ,符合位“0”

  73.     clr c          ;//C  = 0

  74.     rrc a         ;//把零右移进A

  75.     mov keydata,a     ;//保存

  76.     inc r7        ;//计数器加1

  77.     cjne r7,#8,nextbit   ;//是否满8位

  78.     inc r6        ;//计数器加1

  79.     cjne r6,#2,last_8 ;//是第一字节已经满

  80.     sjmp seach    ;//

  81. last_8:           ;//如果为第二字节

  82.     mov keydata+1,a   ;//则保存第一字节到31h

  83.     mov r7,#0     ;//清零R7

  84.     sjmp nextbit      ;//

  85. seach:            ;//匹配按键编码

  86.     mov r0,#-2  ;//按键编码字节个数计数器

  87.     mov r1,#-1  ;//按键顺序计数器

  88. seach1:           ;//

  89.         inc r0       ;//

  90. seach2:           ;//

  91.     inc r0        ;//

  92.     inc r1        ;//

  93.     cjne r1,#29,compare  ;//是否R1=29

  94.     sjmp exit0    ;//

  95. compare:          ;//开始匹配

  96.     mov a,r0      ;//

  97.     mov dptr,#keycode ;//地址指针指向码表首址

  98.     movc a,@a+dptr    ;//取码

  99.     cjne a,keydata,seach1    ;//比较

  100.     inc r0        ;//R0+1,再比较下一字节(每个按键编码为2字节)

  101.     mov a,r0      ;//

  102.     ;mov dptr,#keycode  ;//

  103.     movc a,@a+dptr    ;//比较

  104.     cjne a,keydata+1,seach2  ;//是否匹配,不匹配则继续跟下一字节比较

  105.     mov p1,r1         ;//如果匹配,把按键顺序号输出到p1

  106. send:             ;//

  107.     mov tmod,#20h     ;   //设置timer 1,mode 2

  108.     mov tl1,#0fdh     ;//设置定时器初值

  109.     mov th1,#0fdh     ;//

  110.     mov scon,#01010000b;//以上设置,即设置串口波特率系数为:9600,8,1,0

  111.     setb tr1      ;//启动定时器1

  112. loop_s:       ;//

  113.     mov sbuf,r1    ;//把R1(按键顺序号)输出到串口

  114.     jnb ti,[        DISCUZ_CODE_7        ]nbsp;     ;//等待是否发送完毕

  115.     clr ti        ;//发送完毕,清零TI

  116. exit0:            ;//

  117. ljmp main         ;//循环



  118. keycode:          ;//每两字节代表一个按键的编码

  119. db 11111000b,00000000b,    11111100b,00000000b,    11111001b,11000000b

  120. db 11111100b,11000000b,    11111010b,00000000b,    11111010b,00100000b

  121. db 11111010b,01000000b,    11111010b,01100000b,    11111010b,10000000b

  122. db 11111010b,10100000b,    11111010b,11000000b,    11111010b,11100000b

  123. db 11111011b,00000000b,    11111011b,00100000b,    11111011b,01000000b

  124. db 11111011b,01100000b,    11111111b,01100000b,    11111111b,10100000b

  125. db 10001100b,10001110b,    10001101b,11101110b,    10001100b,10101110b

  126. db 10001101b,11001110b,    11111000b,11100000b,    11111100b,10000000b

  127. db 11111100b,01000000b,    11111001b,10100000b,    11111100b,10100000b

  128. db 11111100b,01100000b

  129. end
复制代码

原程序.asm (2.37 KB, 下载次数: 5)
回复

使用道具 举报

 楼主| 发表于 2011-10-10 14:29:40 | 显示全部楼层

回复 支持 反对

使用道具 举报

发表于 2012-9-24 21:59:46 | 显示全部楼层
楼主那个girder 附件是个损坏的压缩包。
回复 支持 反对

使用道具 举报

发表于 2013-4-19 17:05:26 | 显示全部楼层
楼主的动手能力太强了。我正想弄红外遥控呢。参考。O(∩_∩)O~
回复 支持 反对

使用道具 举报

您需要登录后才可以回帖 登录 | 立即注册

本版积分规则

QQ|手机版|联系我们|闽公网安备 35012102000020号|圣源电子 ( 闽ICP备11020110号 )

GMT+8, 2024-3-28 18:22 , Processed in 0.049123 second(s), 21 queries .

Powered by Discuz! X3.4

© 2001-2017 Comsenz Inc.

快速回复 返回顶部 返回列表